VB6 - transparent images

[FuRbY*]

a current software assignment requires us to create a program where a user can select certain features and it will generate a persons face. im having trouble with adding things like hair to the head without have the transparent images (created in PSP) maintain a white background.

help.

[slpz]

rofl, im doing vb6 atm but nothing near wat u had jus said.

im making an application form which allows the user to save his data then calc prices for product etc.. urs seems hard

cant help u cuz im programming noob

[Henry]

http://www.codeguru.com/csharp/.net/...cle.php/c4661/

It's for .net but it should work.

The magic of google for everything programming related

Edit: Apparently it won't work for vb6. Try this http://en.allexperts.com/q/Visual-Ba...re-Boxes-1.htm

That's pretty loltastic

[FuRbY*]

Originally Posted by Henry

http://www.codeguru.com/csharp/.net/...cle.php/c4661/

It's for .net but it should work.

The magic of google for everything programming related

Edit: Apparently it won't work for vb6. Try this http://en.allexperts.com/q/Visual-Ba...re-Boxes-1.htm

that is quite a bit of code. its a yr11 assignment and if it requires that much coding....

[Henry]

I just post what the internets tell me man. I'd help more but VB aint my thang :P

btw those links took me about 2 seconds to find if you try for 2 mins you might get a better site. I doubt it though I'm the pro Googler

[chemicalNova]

You want the white parts to be transparent? You'll need to generate a mask for the picture. Something like this:

PHP Code:

' chemicalNova

Option Explicit

Private Declare Function BitBlt Lib "gdi32" _
  (ByVal hDCDest As Long, ByVal XDest As Long, _
   ByVal YDest As Long, ByVal nWidth As Long, _
   ByVal nHeight As Long, ByVal hDCSrc As Long, _
   ByVal xSrc As Long, ByVal ySrc As Long, _
   ByVal dwRop As Long) As Long

Private Declare Function CreateBitmap Lib "gdi32" _
  (ByVal nWidth As Long, _
   ByVal nHeight As Long, _
   ByVal nPlanes As Long, _
   ByVal nBitCount As Long, _
   lpBits As Any) As Long

Private Declare Function SetBkColor Lib "gdi32" _
   (ByVal hdc As Long, _
    ByVal crColor As Long) As Long

Private Declare Function SelectObject Lib "gdi32" _
  (ByVal hdc As Long, _
   ByVal hObject As Long) As Long

Private Declare Function CreateCompatibleBitmap Lib "gdi32" _
  (ByVal hdc As Long, _
   ByVal nWidth As Long, _
   ByVal nHeight As Long) As Long

Private Declare Function CreateCompatibleDC Lib "gdi32" _
   (ByVal hdc As Long) As Long

Private Declare Function DeleteDC Lib "gdi32" _
   (ByVal hdc As Long) As Long

Private Declare Function DeleteObject Lib "gdi32" _
   (ByVal hObject As Long) As Long

Sub TransparentBlt(OutDstDC As Long, DstDC As Long, SrcDC As Long, SrcX As Integer, SrcY As Integer, DstX As Integer, DstY As Integer, TransColor As Long)
   
  'DstDC- Device context into which image must be
  'drawn transparently
  
  'OutDstDC- Device context into image is actually drawn,
  'even though it is made transparent in terms of DstDC

  'Src- Device context of source to be made transparent
  'in color TransColor

  'SrcRect- Rectangular region within SrcDC to be made
  'transparent in terms of DstDC, and drawn to OutDstDC

  'DstX, DstY - Coordinates in OutDstDC (and DstDC)
  'where the transparent bitmap must go. In most
  'cases, OutDstDC and DstDC will be the same
  Dim nRet As Long, W As Integer, H As Integer
  Dim MonoMaskDC As Long, hMonoMask As Long
  Dim MonoInvDC As Long, hMonoInv As Long
  Dim ResultDstDC As Long, hResultDst As Long
  Dim ResultSrcDC As Long, hResultSrc As Long
  Dim hPrevMask As Long, hPrevInv As Long
  Dim hPrevSrc As Long, hPrevDst As Long

  W = SrcX
  H = SrcY
   
 'create monochrome mask and inverse masks
  MonoMaskDC = CreateCompatibleDC(DstDC)
  MonoInvDC = CreateCompatibleDC(DstDC)
  hMonoMask = CreateBitmap(W, H, 1, 1, ByVal 0&)
  hMonoInv = CreateBitmap(W, H, 1, 1, ByVal 0&)
  hPrevMask = SelectObject(MonoMaskDC, hMonoMask)
  hPrevInv = SelectObject(MonoInvDC, hMonoInv)
   
 'create keeper DCs and bitmaps
  ResultDstDC = CreateCompatibleDC(DstDC)
  ResultSrcDC = CreateCompatibleDC(DstDC)
  hResultDst = CreateCompatibleBitmap(DstDC, W, H)
  hResultSrc = CreateCompatibleBitmap(DstDC, W, H)
  hPrevDst = SelectObject(ResultDstDC, hResultDst)
  hPrevSrc = SelectObject(ResultSrcDC, hResultSrc)
   
'copy src to monochrome mask
  Dim OldBC As Long
  OldBC = SetBkColor(SrcDC, TransColor)
  nRet = BitBlt(MonoMaskDC, 0, 0, W, H, SrcDC, _
                0, 0, vbSrcCopy)
  TransColor = SetBkColor(SrcDC, OldBC)
   
 'create inverse of mask
  nRet = BitBlt(MonoInvDC, 0, 0, W, H, _
                MonoMaskDC, 0, 0, vbNotSrcCopy)
   
 'get background
  nRet = BitBlt(ResultDstDC, 0, 0, W, H, _
                DstDC, DstX, DstY, vbSrcCopy)
   
 'AND with Monochrome mask
  nRet = BitBlt(ResultDstDC, 0, 0, W, H, _
                MonoMaskDC, 0, 0, vbSrcAnd)
   
 'get overlapper
  nRet = BitBlt(ResultSrcDC, 0, 0, W, H, SrcDC, _
                0, 0, vbSrcCopy)
   
 'AND with inverse monochrome mask
  nRet = BitBlt(ResultSrcDC, 0, 0, W, H, _
                MonoInvDC, 0, 0, vbSrcAnd)
   
'XOR these two
  nRet = BitBlt(ResultDstDC, 0, 0, W, H, _
                ResultSrcDC, 0, 0, vbSrcInvert)
   
 'output results
  nRet = BitBlt(OutDstDC, DstX, DstY, W, H, _
                ResultDstDC, 0, 0, vbSrcCopy)
   
 clean up
  hMonoMask = SelectObject(MonoMaskDC, hPrevMask)
  DeleteObject hMonoMask

  hMonoInv = SelectObject(MonoInvDC, hPrevInv)
  DeleteObject hMonoInv

  hResultDst = SelectObject(ResultDstDC, hPrevDst)
  DeleteObject hResultDst

  hResultSrc = SelectObject(ResultSrcDC, hPrevSrc)
  DeleteObject hResultSrc

  DeleteDC MonoMaskDC
  DeleteDC MonoInvDC
  DeleteDC ResultDstDC
  DeleteDC ResultSrcDC

End Sub 


..and used like:

PHP Code:

TransparentBlt To.hdc, To.hdc, From.hdc, Width, Height, x, y, RGB(255, 255, 255)  255,255,255 = white 


chem

[chemicalNova]

Due to the extreme lack of syntax highlighting capabilities of these forums I've uploaded the project.

This example is one I wrote for someone on vbforums.com.

http://www.cdeliasoftware.com/transparent.zip

Run the project, and click the button.. the black is transparent'ed.

chem

[FuRbY*]

Originally Posted by chemicalNova

Due to the extreme lack of syntax highlighting capabilities of these forums I've uploaded the project.

This example is one I wrote for someone on vbforums.com.

http://www.cdeliasoftware.com/transparent.zip

Run the project, and click the button.. the black is transparent'ed.

chem

thankyou for some coding with visuals. will try implementing it.

btw, what am i changing to get the black transparency to white transparency?
does it also matter whether its a picture or image box?

[chemicalNova]

Changing it from black to white is as simple as changing the last 0 in the example I gave you, to RGB(255,255,255).

ImageBoxes are terrible controls. PictureBoxes, are basically a movable Device Context.

ImageBoxes can load Pictures with transparency.. but you cannot change the contents of an ImageBox. PictureBoxes can't load with transparency, but you can change the contents of the picturebox.

So to answer your question.. yes, it MUST be a PictureBox for that particular piece of code to work.

chem